UE2 - UT2kX Hud Help [Ammo Meters]

meowcat said:

The "slantiness" is the only possible problem with that hud texture.

There are several functions in the canvas.uc class that allow you to draw only a boxed shape portion of a texture (by passing in the starting point coordinate in the texture and how many pixels to the right and down, or left and up if I recall correctly by using negative pixel values). See the DrawTile and SetPos function specifically.

The only way I can think of dealing with the slanted texture is to optionally place a mask texture that is shifted into the base texture (using a Shader combined with a TexScaler and the UOffset

Click to expand...

Wormbo said:

Pro tip: Don't post BMPs or TGAs on the internet, use PNG instead. The PNG format can be saved with or without alpha channel, allowing it to losslessly store anything you'd also store in a BMP or TGA file - except that PNG usually is much smaller. (Your 1MB BMP's content could be squeezed into a 20kB PNG file.)

But to elaborate on meowcat's masking idea: The type of mask obviously depends on the draw style you use. If you draw the texture using STY_Alpha (Style = 5), you will need to modify the alpha channel. If, however, you draw it using STY_Translucent (Style = 3), you will actually have to use a Combiner to multiply the texture with a white mask shifted to the appropriate position using the same TexScaler method.
I've attached an example modification of your HUD texture to show this kind of mask shape. The first mask can be used for the small bullet icons. The black space below it also belongs to this mask, so you can move it upwards to mask out the entire lower line(s). Use an inverted version of this mask to draw the other bullets in a different color. Alternatively, if you only want to dim used-up bullets, you can brighten up the black part to some gray value.
The second mask should work for all three of the other small bullet types and possibly also for the bomb-shaped icons, though obviously they all need different start offsets.
The third mask is supposed to be used for the large bullets.

Click to expand...

VendorX said:

Use SpriteWidget ... You don't need separate textures to each type of ammo - texture from your first post is all you need, only add alpha channel to it if you don't have one.

Click to expand...

VendorX said:

To be honest, I have no idea why there is gradient alpha - maybe for colour shifting ...

You can do this in two ways:
- use from original texture the same part of image for every row.

- or delete original alpha channel and make new one. If you have Photoshop go to Image -> Calculations and in Blending select Color Dodge - this should give you nice new alpha channel.

To change colour use Tints ...
To progress bar by one more / less bullet use Scale or change the TextureCoords.

To display ammo rows use if statements, e.g.:
- first row will be always displayed
- second only if ammo count is greater than 20
- third only if ammo count is greater than 40

Another way (as you mentioned ...) is to draw image of one bullet multiplied by ammo count - choice is yours ...

As for Halo shaders, it's like with .pcx in UE - you can choose colour to become transparent.

Click to expand...

meowcat said:

ForrestMarkX; Do you have UT2k4 to run some tests? Here is some sample code that I placed in a test subclass of the Assault Rifle. It uses the version of the texture that Wormbo modified so nicely (which I converted to a .dds file), to correctly shift ammo icons. Note that there is some slight adjustments needed to the pixel offsets as some icon get only partially cutoff, but in general works the way you want (I think).

Code:

//===============
// Assault Rifle
// Also use as a test bed for the alpha ammo icons
//===============
class ddar extends AssaultRifle
    config(user);

/* This texture is 512 x 512 pixels wide
  AR: the bullets are 10 pixels wide by 17 pixels tall
      bullet row icons (3 rows) can be drawn from pixels (0, 0) to (226, 52)
      bullet row mask (3 rows) can be drawn from pixels (0, 170) to (226, 224)
  Shotgun: the shells are 18 pixels wide by 34 pixels tall
        shell row icons (1 row) can be drawn from pixels (0, 53) to (221, 86)
        shell row mask (1 rows) can be drawn from pixels (0, 266) to (224, 303)

*/
#exec TEXTURE IMPORT File=classes\hud_ammo_alphas.dds Name=hud_ammo_alphas Mips=Off MASKED=0 ALPHA=1 LODSET=5 UCLAMPMODE=CLAMP VCLAMPMODE=CLAMP

var shader Ammo_Shad;
var TexScaler Ammo_Scaler;
var FinalBlend Ammo_FB;
var	int ClipCount, OldClipCount; // just a test/convenience variable to show the clip count display changing.
var int ClipSize;

simulated function PostBeginPlay(){
     super.PostBeginPlay();

     ClipCount = ClipSize;
     // Adjust the AmmoScaler.UOffset variable (in pixels) to move it along
     Ammo_Scaler = TexScaler(Level.ObjectPool.AllocateObject(class'TexScaler'));
     Ammo_Scaler.Material = texture'hud_ammo_alphas';

     Ammo_Shad = shader(Level.ObjectPool.AllocateObject(class'shader'));
     Ammo_shad.Diffuse = Ammo_Scaler;
     Ammo_shad.Opacity = texture'hud_ammo_alphas';

     Ammo_FB = FinalBlend(Level.ObjectPool.AllocateObject(class'FinalBlend'));
     Ammo_FB.Material = Ammo_shad;
     Ammo_FB.FrameBufferBlending = FB_brighten; // or maybe FB_AlphaBlend
}

simulated function Destroyed(){
     // now free the materials.
     Level.ObjectPool.FreeObject(Ammo_FB);
     Level.ObjectPool.FreeObject(Ammo_shad);
     Level.ObjectPool.FreeObject(Ammo_scaler);
     super.Destroyed();
}

simulated function IncrementFlashCount(int Mode)
{
    super.IncrementFlashCount(Mode);
    ClipCount--;
    if(ClipCount < 0) ClipCount = ClipSize; // constantly roll over
}

simulated event RenderOverlays( Canvas C )
{
    local int ClipRemainder;
    if (Instigator == None)
        return;
    Super.RenderOverlays(C);
    // now draw the ammo status to the upper left corner of the canvas
    // AR bullet list
    if(true){
       //ClipSize = 60; // this is how many little icons are in the texture
       if(OldClipCount != ClipCount){
           //ClipRemainder = ClipCount % ClipSize;// constantly roll this over and grab the amount less than the clip size

           ClipRemainder = ClipCount; // yeah this is redundant, but left it in incase you want to roll-over a byte for this example purposes
           // three rows with three different cases to take into account the skew
           // since each row is slightly offset to the left from the one above
           if(ClipRemainder > 40){
               // UOffset = Initial pixel skew offset into the row + (AR Bullet Pixel width * (empties in row))
               Ammo_Scaler.UOffset = 0 + (10 * (20 - (ClipRemainder - 40)));
               Ammo_Scaler.VOffset = 170;
           }else if (ClipRemainder > 20){
               Ammo_Scaler.UOffset = 5 + (10 * (20 - (ClipRemainder - 20)));
               Ammo_Scaler.VOffset = 188;
           }else{
               Ammo_Scaler.UOffset = 10 + (10 * (20 - ClipRemainder));
               Ammo_Scaler.VOffset = 206; // so that only the top row gets a color, the bottom two rows will be in black
           }
           OldClipCount = ClipCount;
       }
       C.Style = 5;
   	   C.SetDrawColor (255, 255, 255, 255); // tweak this for a different color
   	   C.SetPos(C.SizeX * 0.03, C.SizeY * 0.15); // start a little ways away from the upper left corner
       // now draw AR bullet 'chunk' out of the Final blend
       C.DrawTile(Ammo_FB, C.SizeX * 0.2, C.SizeY * 0.055, 0.0, 0.0, 226, 52);
    }
}


defaultproperties
{
    ClipSize=60 // adjust this based on which bullet icons you are using
    PickupClass=class'ddarPickup'
    AttachmentClass=class'AssaultAttachment'
}

You will have to tweak the other fixed/hard coded pixel offset values for the other icons and you may need to further adjust the texture, though Wormbo's edited version should be able to be worked for all of those icons.

Click to expand...

meowcat said:

ForrestMarkX; Do you have UT2k4 to run some tests? Here is some sample code that I placed in a test subclass of the Assault Rifle. It uses the version of the texture that Wormbo modified so nicely (which I converted to a .dds file), to correctly shift ammo icons. Note that there is some slight adjustments needed to the pixel offsets as some icon get only partially cutoff, but in general works the way you want (I think).

You will have to tweak the other fixed/hard coded pixel offset values for the other icons and you may need to further adjust the texture, though Wormbo's edited version should be able to be worked for all of those icons.

Click to expand...